grimm-nixos-laptop/fake_flake.nix

{ pkgs, lib, config, ... }:
let
  nivSources = import ./nix/sources.nix;
  asGithubRef = src: "github:${src.owner}/${src.repo}/${src.rev}";
in
{
  imports = [
    "${nivSources.agenix}/modules/age.nix"
    (import "${nivSources.lix-module}/module.nix" { lix = nivSources.lix-pkg; })
    (builtins.getFlake (asGithubRef nivSources.chaotic)).nixosModules.default # fixme: ideally we'd not rely on the flake syntax to load the module
  ];

  nixpkgs.hostPlatform = "x86_64-linux";

  nixpkgs.pkgs = import nivSources.nixpkgs { allowUnfree = true; };

  nixpkgs.overlays = lib.singleton (final: prev: {
    agenix = final.callPackage "${nivSources.agenix}/pkgs/agenix.nix" { };
  });

  nix.settings.extra-substituters = [
    "https://cache.lix.systems"
    "https://nyx.chaotic.cx/"
  ];

  nix.settings.trusted-public-keys = [
    "cache.lix.systems:aBnZUw8zA7H35Cz2RyKFVs3H4PlGTLawyY5KRbvJR8o="
    "nyx.chaotic.cx-1:HfnXSw4pj95iI/n17rIDy40agHj12WfF+Gqk6SonIT8="
    "chaotic-nyx.cachix.org-1:HfnXSw4pj95iI/n17rIDy40agHj12WfF+Gqk6SonIT8="
  ];
}