grimm-nixos-laptop/common/tooling/default.nix

{
  pkgs,
  config,
  lib,
  ...
}:
let
  cfg = config.grimmShared;
in
{
  imports = [
    ./lilypond.nix
    ./nix.nix
    ./security.nix
    ./python.nix
  ];

  config =
    with cfg;
    lib.mkIf (enable && tooling.enable) {
      environment.systemPackages =
        with pkgs;
        [
          (writeShellScriptBin "systemd-owner" "systemctl show -pUser,UID $@")
          (writeShellScriptBin "tree" "${lib.getExe pkgs.eza} -T --git -lh --no-permissions --no-user --no-filesize --no-time")
          (writeShellScriptBin "spawn" ''exec "$@" &> /dev/null &'')
          (writeShellScriptBin "silent-add" "git add --intent-to-add $@ ; git update-index --assume-unchanged $@")

          urlencode
          pstree
          dos2unix
          treefmt
          file
          wget
          hyfetch
          util-linux
          btop
          neovim-remote
          linuxPackages.perf
          eza

          gcc
          jdk17
          pkg-config
          unzip
          p7zip

          tea

          fbcat
          gomuks
          ranger

          visualvm
          imagemagick
          nmap

          parted
          glib
          glibc
          expect
        ]
        ++ lib.optionals cfg.graphical [
          wev
          qdirstat
          libva-utils
          gparted
          jetbrains.clion
          jetbrains.idea-community
        ];

      programs.git = {
        enable = true;
        lfs.enable = true;
        config = {
          init.defaultBranch = "main";
          credential.username = cfg.tooling.git_user;
          core.editor = lib.getExe pkgs.neovim;
          user.name = cfg.tooling.git_user;
          user.email = cfg.tooling.git_email;
          push.autoSetupRemote = true;
          core.autocrlf = "input";
          commit.gpgsign = true;
          pull.rebase = true;
          alias = {
            pfusch = "push --force-with-lease --force-if-includes";
            fuck = "reset HEAD~1";
            fixup = "commit --fixup";
          };
        };
      };

      environment.shellAliases = {
        ":q" = "exit";
        "ls" = "eza";
        "lix" = "nix";
      };

      programs.tmux = {
        enable = true;
        historyLimit = 42000;
        #keyMode = "vi";
      };

      # virtualisation.docker.enable = true;

      services.dbus.implementation = "broker";

      grimmShared.tooling.nvim = {
        plugins = with pkgs.vimPlugins; [
          fugitive
          nvim-lspconfig
        ];
      };

      boot.tmp.cleanOnBoot = true;
      zramSwap.enable = true;

      programs.neovim = {
        enable = true;
        viAlias = true;
        defaultEditor = true;
        configure = {
          customRC =
            let
              luarc = pkgs.writeText "init.lua" (lib.concatLines tooling.nvim.extraLuaRC);
            in
            ''
              set number
              set hidden
              set fileencodings=utf-8
              set nocompatible
              set clipboard+=unnamedplus
              set ff=unix

              luafile ${luarc}

              if filereadable($HOME . "/.vimrc")
                source ~/.vimrc
              endif
            '';
          packages.myVimPackage = {
            start = tooling.nvim.plugins;
            opt = [ ];
          };
        };
      };

      programs.ssh = {
        startAgent = true;
        enableAskPassword = graphical;
        askPassword = lib.mkIf graphical (lib.getExe pkgs.lxqt.lxqt-openssh-askpass);
      };
      programs.thefuck.enable = true;
    };

  options.grimmShared.tooling = with lib; {
    enable = mkEnableOption "grimm-tooling";

    nvim = {
      plugins = mkOption {
        type = types.listOf types.package;
        default = [ ];
        description = "Extra vim plugins to include";
      };

      extraLuaRC = mkOption {
        type = types.listOf types.nonEmptyStr;
        default = [ ];
        description = "Extra init LUA scripts";
      };
    };

    git_user = mkOption {
      type = types.str;
      default = "Grimmauld";
      description = "Username for git to use";
    };

    git_email = mkOption {
      type = types.str;
      default = "${config.grimmShared.tooling.git_user}@grimmauld.de";
      description = "Email for git to use";
    };
  };
}