grimm-nixos-laptop/hardening/apparmor/apparmor-d-package.nix

{
  buildGoModule,
  fetchFromGitHub,
  lib,
  unstableGitUpdater,
}:
buildGoModule {
  pname = "apparmor-d";
  version = "unstable-2025-01-13";

  src = fetchFromGitHub {
    rev = "f1182b27bb64a3bf44e92a4bafb58178ebfbf5ac";
    owner = "roddhjav";
    repo = "apparmor.d";
    hash = "sha256-3Ofv7Eam2/CXRNM84E0H97RrLWQEzDeSM6wYykzlLAM=";
  };

  vendorHash = null;

  doCheck = false;

  patches = [
    ./apparmor-d-prebuild.patch
  ];

  subPackages = [
    "cmd/prebuild"
    "cmd/aa-log"
  ];

  passthru.updateScript = unstableGitUpdater { };

  postInstall = ''
    mkdir -p $out/etc

    DISTRIBUTION=nixos $out/bin/prebuild --abi 4 # fixme: replace with nixos support once available

    mv .build/apparmor.d $out/etc
    rm $out/bin/prebuild
  '';

  meta = {
    description = "Full set of AppArmor profiles (~ 1500 profiles) ";
    homepage = "https://github.com/roddhjav/apparmor.d";
    license = lib.licenses.gpl2Only;
    mainProgram = "aa-log";
    maintainers = with lib.maintainers; [ grimmauld ];
    platforms = lib.platforms.linux;
  };
}