{
  buildGoModule,
  fetchFromGitHub,
  lib,
  unstableGitUpdater,
}:
buildGoModule {
  pname = "apparmor-d";
  version = "unstable-2025-02-18";

  src = fetchFromGitHub {
    rev = "af85db9148b17bb37b4d73454e78d4efec4c2db9";
    owner = "roddhjav";
    repo = "apparmor.d";
    hash = "sha256-mCc1DQXQvzeeA+sq67zK5o18tKByaB5dITmC77j9uEM=";
  };

  vendorHash = null;

  doCheck = false;
  dontCheckForBrokenSymlinks = true;

  patches = [
    ./apparmor-d-prebuild.patch
  ];

  subPackages = [
    "cmd/prebuild"
    "cmd/aa-log"
  ];

  passthru.updateScript = unstableGitUpdater { };

  postInstall = ''
    mkdir -p $out/etc

    DISTRIBUTION=nixos $out/bin/prebuild --abi 4 # fixme: replace with nixos support once available

    mv .build/apparmor.d $out/etc
    rm $out/bin/prebuild
  '';

  meta = {
    description = "Full set of AppArmor profiles (~ 1500 profiles) ";
    homepage = "https://github.com/roddhjav/apparmor.d";
    license = lib.licenses.gpl2Only;
    mainProgram = "aa-log";
    maintainers = with lib.maintainers; [ grimmauld ];
    platforms = lib.platforms.linux;
  };
}