{ pkgs, config, lib, inputs, ... }:
let
  cfg = config.grimmShared;
in
{
  imports = [
    ./lilypond.nix
  ];

  config = with cfg; lib.mkIf (enable && tooling.enable) {
    environment.systemPackages = with pkgs; [
      (writeShellScriptBin "silent-add" "git add --intent-to-add $@ ; git update-index --assume-unchanged $@")
      (writeShellScriptBin "systemd-owner" "systemctl show -pUser,UID $@")
      (writeShellScriptBin "nix-referrers" "nix-store --query --referrers $@")
      (writeShellScriptBin "nixpkgs-review-head" "nixpkgs-review rev HEAD")
      (writeShellScriptBin "fmt-all" "find ./**.nix -readable -writable -type f | xargs nixpkgs-fmt")
      (writeShellScriptBin "lsiommu" ./lsiommu)

      nixpkgs-review
      nixpkgs-fmt
      nixd
      gcc
      jdk17
      python3
      pkg-config
      unzip
      p7zip

      tea

      fbcat
      gomuks
      gotop
      ranger
      nix-search-cli

      wget
      tree
      file
      pypy3
      util-linux
      visualvm
      imagemagick
      nmap

      hyfetch
      parted
      glib
      glibc
      # inputs.nix-locate.packages."${system}".default
      inputs.hammering.packages."${system}".default
      nix-output-monitor
      expect

      neovim-remote
    ] ++ lib.optionals cfg.graphical [
      qdirstat
      libva-utils
      glxinfo
      alacritty
      vulkan-tools
      pdfarranger
      nomacs
      gparted
    ];

    programs.git = {
      enable = true;
      lfs.enable = true;
      config = {
        init.defaultBranch = "main";
        credential.username = cfg.tooling.git_user;
        core.editor = lib.getExe pkgs.neovim;
        user.name = cfg.tooling.git_user;
        user.email = cfg.tooling.git_email;
        push.autoSetupRemote = true;
      };
    };

    programs.tmux = {
      enable = true;
      historyLimit = 42000;
      #keyMode = "vi";
    };

    # virtualisation.docker.enable = true;


    grimmShared.tooling.nvim.plugins = with pkgs.vimPlugins; [
      vim-nix
      vim-scala
      fugitive
    ];

    programs.neovim = {
      enable = true;
      viAlias = true;
      defaultEditor = true;
      configure = {
        customRC =
          let
            luarc = pkgs.writeText "init.lua" (lib.concatLines tooling.nvim.extraLuaRC);
          in
          ''
            set number
            set hidden
            set fileencodings=utf-8
            set nocompatible
            set clipboard+=unnamedplus

            luafile ${luarc}

            if filereadable($HOME . "/.vimrc")
              source ~/.vimrc
            endif
          '';
        packages.myVimPackage = {
          start = tooling.nvim.plugins;
          opt = [ ];
        };
      };
    };

    programs.xonsh = {
      enable = true;
      package = pkgs.xonsh.override {
        extraPackages = ps: with ps; [
          requests
          matplotlib
          numpy
          scipy
        ];
      };
    };
    programs.ssh.startAgent = true;
    programs.thefuck.enable = true;
  };

  options.grimmShared.tooling = with lib; {
    enable = mkEnableOption "grimm-tooling";

    nvim = {
      plugins = mkOption {
        type = types.listOf types.package;
        default = [ ];
        description = "Extra vim plugins to include";
      };

      extraLuaRC = mkOption {
        type = types.listOf types.nonEmptyStr;
        default = [ ];
        description = "Extra init LUA scripts";
      };
    };

    pass = lib.mkEnableOption "Enables password-store, gnupg and such secret handling";

    git_user = mkOption {
      type = types.str;
      default = "Grimmauld";
      description = "Username for git to use";
    };

    git_email = mkOption {
      type = types.str;
      default = "${config.grimmShared.tooling.git_user}@grimmauld.de";
      description = "Email for git to use";
    };
  };
}