Pixel-Composer/scripts/node_camera/node_camera.gml

function Node_Camera(_x, _y, _group = noone) : Node_Processor(_x, _y, _group) constructor {
	name = "Camera";
	preview_alpha = 0.5;
	
	shader = sh_camera;
	uni_backg   = shader_get_sampler_index(shader, "backg");
	uni_scene   = shader_get_sampler_index(shader, "scene");
	uni_dim_scn = shader_get_uniform(shader, "scnDimension");
	uni_dim_cam = shader_get_uniform(shader, "camDimension");
	uni_pos     = shader_get_uniform(shader, "position");
	uni_zom     = shader_get_uniform(shader, "zoom");
	uni_sam_mod = shader_get_uniform(shader, "sampleMode");
	uni_blur    = shader_get_uniform(shader, "blur");
	uni_fix_bg  = shader_get_uniform(shader, "fixBG");
	
	inputs[| 0] = nodeValue("Background", self, JUNCTION_CONNECT.input, VALUE_TYPE.surface, 0);
	inputs[| 1] = nodeValue("Focus area", self, JUNCTION_CONNECT.input, VALUE_TYPE.integer, [ 0, 0, 16, 16, AREA_SHAPE.rectangle ])
		.setDisplay(VALUE_DISPLAY.area, function() { return getDimension(0); });
	
	inputs[| 2] = nodeValue("Zoom", self, JUNCTION_CONNECT.input, VALUE_TYPE.float, 1)
		.setDisplay(VALUE_DISPLAY.slider, [ 0.01, 4, 0.01 ]);
	
	inputs[| 3] = nodeValue("Oversample mode", self, JUNCTION_CONNECT.input, VALUE_TYPE.integer, 0, "How to deal with pixel outside the surface.\n    - Empty: Use empty pixel\n    - Clamp: Repeat edge pixel\n    - Repeat: Repeat texture.")
		.setDisplay(VALUE_DISPLAY.enum_scroll, [ "Empty", "Repeat" ]);
	
	inputs[| 4] = nodeValue("Fix background", self, JUNCTION_CONNECT.input, VALUE_TYPE.boolean, false);
	
	outputs[| 0] = nodeValue("Surface out", self, JUNCTION_CONNECT.output, VALUE_TYPE.surface, noone);
	
	input_display_list = [
		["Background",   true], 0, 4, 3, 
		["Camera",		false], 1, 2,
		["Elements",	 true], 
	];
	
	attribute_surface_depth();
	
	input_display_len = array_length(input_display_list);
	input_fix_len	  = ds_list_size(inputs);
	data_length		  = 3;
	
	temp_surface = [ noone, noone ];
	
	function createNewInput() {
		var index = ds_list_size(inputs);
		var _s    = floor((index - input_fix_len) / data_length);
		
		inputs[| index + 0] = nodeValue($"Element {_s}", self, JUNCTION_CONNECT.input, VALUE_TYPE.surface, 0);
		
		inputs[| index + 1] = nodeValue($"Parallax {_s}", self, JUNCTION_CONNECT.input, VALUE_TYPE.float, [ 0, 0, 0 ] )
			.setDisplay(VALUE_DISPLAY.vector)
			.setUnitRef(function(index) { return getDimension(index); });
		
		inputs[| index + 2] = nodeValue($"Oversample {_s}", self, JUNCTION_CONNECT.input, VALUE_TYPE.integer, 0)
			.setDisplay(VALUE_DISPLAY.enum_scroll, [ "Empty", "Repeat" ]);
		
		array_append(input_display_list, [ index + 0, index + 1, index + 2 ]);
	}
	if(!LOADING && !APPENDING) createNewInput();
	
	static refreshDynamicInput = function() {
		var _in = ds_list_create();
		
		for( var i = 0; i < input_fix_len; i++ )
			ds_list_add(_in, inputs[| i]);
		
		array_resize(input_display_list, input_display_len);
		
		for( var i = input_fix_len; i < ds_list_size(inputs); i += data_length ) {
			if(inputs[| i].value_from) {
				ds_list_add(_in, inputs[| i + 0]);
				ds_list_add(_in, inputs[| i + 1]);
				ds_list_add(_in, inputs[| i + 2]);
				
				array_push(input_display_list, i + 0);
				array_push(input_display_list, i + 1);
				array_push(input_display_list, i + 2);
			} else {
				delete inputs[| i + 0];
				delete inputs[| i + 1];
				delete inputs[| i + 2];
			}
		}
		
		for( var i = 0; i < ds_list_size(_in); i++ )
			_in[| i].index = i;
		
		ds_list_destroy(inputs);
		inputs = _in;
		
		createNewInput();
	}
	
	static onValueFromUpdate = function(index) {
		if(index < input_fix_len) return;
		if(LOADING || APPENDING) return;
		
		refreshDynamicInput();
	}
	
	static getPreviewValue = function() { return inputs[| 0]; }
	
	static drawOverlay = function(active, _x, _y, _s, _mx, _my, _snx, _sny) {
		if(array_length(current_data) == 0) return;
		
		var _out = outputs[| 0].getValue();
		var _area = current_data[1];
		var _zoom = current_data[2];
		
		var _cam_x = _x + (_area[0] - _area[2] * _zoom) * _s;
		var _cam_y = _y + (_area[1] - _area[3] * _zoom) * _s;
		
		draw_surface_ext_safe(_out, _cam_x, _cam_y, _s * _zoom, _s * _zoom);
		inputs[| 1].drawOverlay(active, _x, _y, _s, _mx, _my, _snx, _sny);
		
		draw_set_color(COLORS._main_accent);
		var x0 = _cam_x;
		var y0 = _cam_y;
		var x1 = x0 + _area[2] * 2 * _zoom * _s;
		var y1 = y0 + _area[3] * 2 * _zoom * _s;
		
		draw_rectangle_dashed(x0, y0, x1, y1);
	}
	
	static process_data = function(_outSurf, _data, _output_index, _array_index) {
		if(!is_surface(_data[0])) return;
		var _area = _data[1];
		var _zoom = _data[2];
		var _samp = _data[3];
		var _fix  = _data[4];
		var cDep  = attrDepth();
		
		var _cam_x = round(_area[0]);
		var _cam_y = round(_area[1]);
		var _cam_w = round(_area[2]);
		var _cam_h = round(_area[3]);
		
		var _surf_w = round(surface_valid_size(_cam_w * 2));
		var _surf_h = round(surface_valid_size(_cam_h * 2));
		var ppInd   = 0;
		
		_outSurf = surface_verify(_outSurf, _surf_w, _surf_h, cDep);
		temp_surface[0] = surface_verify(temp_surface[0], _surf_w, _surf_h, cDep);
		temp_surface[1] = surface_verify(temp_surface[1], _surf_w, _surf_h, cDep);
		
		var amo = (ds_list_size(inputs) - input_fix_len) / data_length - 1;
		
		surface_set_target(temp_surface[0]);
		DRAW_CLEAR
		BLEND_OVERRIDE;
		if(amo <= 0) {
			if(_fix) {
				if(_samp)	draw_surface_tiled_safe(_data[0], 0, 0);
				else		draw_surface_safe(_data[0], 0, 0);
			} else {
				var sx = _cam_x / _zoom - _cam_w;
				var sy = _cam_y / _zoom - _cam_h;
				if(_samp)	draw_surface_tiled_ext_safe(_data[0], -sx, -sy, 1 / _zoom, 1 / _zoom, c_white, 1);
				else		draw_surface_ext_safe(_data[0], -sx, -sy, 1 / _zoom, 1 / _zoom, 0, c_white, 1);
			}
		} else {
			var sx = _cam_x / _zoom - _cam_w;
			var sy = _cam_y / _zoom - _cam_h;
				
			if(_fix)	draw_surface_safe(_data[0], 0, 0);
			else		draw_surface_tiled_ext_safe(_data[0], sx, sy, 1 / _zoom, 1 / _zoom, c_white, 1);
		}
		BLEND_NORMAL;
		surface_reset_target();
		
		surface_set_target(temp_surface[1]);
		DRAW_CLEAR
		surface_reset_target();
		
		shader_set(shader);
		shader_set_uniform_f(uni_dim_cam, _surf_w, _surf_h);
		shader_set_uniform_f(uni_zom, _zoom);
		
		for( var i = 0; i < amo; i++ ) {
			ppInd = !ppInd;
			
			surface_set_target(temp_surface[ppInd]);
			var ind = input_fix_len + i * data_length;
			
			var _surface = _data[ind];
			var sz       = _data[ind + 1][2];
			var sx       = _data[ind + 1][0] * sz * _cam_x;
			var sy       = _data[ind + 1][1] * sz * _cam_y;
			var _samp    = _data[ind + 2];
			
			var _scnW = surface_get_width(_surface);
			var _scnH = surface_get_height(_surface);
			
			shader_set_uniform_i(uni_sam_mod, _samp);
			shader_set_uniform_f(uni_dim_scn, _scnW, _scnH);
			shader_set_uniform_f(uni_blur, sz);
			shader_set_uniform_f(uni_pos, (_cam_x + sx) / _scnW, (_cam_y + sy) / _scnH);
			shader_set_uniform_i(uni_fix_bg, !i && _fix);
			
			texture_set_stage(uni_backg, surface_get_texture(temp_surface[!ppInd])); //prev surface
			texture_set_stage(uni_scene, surface_get_texture(_surface)); //surface to draw
			draw_sprite_ext(s_fx_pixel, 0, 0, 0, _surf_w, _surf_h, 0, c_white, 1);
			surface_reset_target();
		}
		
		shader_reset();
		
		surface_set_target(_outSurf);
		DRAW_CLEAR
		BLEND_OVERRIDE;
		draw_surface_safe(temp_surface[ppInd], 0, 0);
		BLEND_NORMAL;
		surface_reset_target();
		
		return _outSurf;
	}
	
	static postDeserialize = function() {
		var _inputs = load_map.inputs;
		
		for(var i = input_fix_len; i < array_length(_inputs); i += data_length)
			createNewInput();
	}
}